首先

首先废话不多说，ss-qt5 3.0.1 版本的 DEB 包下载：【点击下载↓】

emmmm… 因为 XZY 的 linux 技术差得一匹所以如果觉得 XZY 打的包不好想自己打包的可以看看下面的废话。。。QwQ

下面是废话

之前搭的 ssr 老不稳定，可能是 ssr 太菜了？QvQ（Update: 我又换回 ssr 了，ssr 大法吼哇）

于是换成了 ss，感觉舒服多了，就没掉过线

但是唯一令人不爽的是 ss 的 linux 客户端 shadowsocks-qt5 官方只提供了.appimage 文件，那种双击打开的那种。。。

双击打开很不习惯，习惯从 dash 打开，双击打开效率低呀。。。

况且不知道为什么 appimage 打开有 bug，界面特别丑而且提示消息里的图片还显示不出来。

于是去网上找，发现官方 ppa 里有，但是没有 18.04 的，不过没关系，我就直接添加了 16.04 的源，然后 apt install。。。装是装成功了，但是虽然显示连接成功，并且网络代理设置也改了，但是就是上不了 google 啥的，但是用 appimage 又能上。。。

我就猜测是 16.04 提供的那个版本太老了。。。可是新版 3.0.1 又只有 appimage。。。

那咋办捏。。。于是我决定自己去编译生成一个.deb 包。。。

怎么搞呢？先去把这两个仓库 clone 下来：

• https://github.com/shadowsocks/libQtShadowsocks
• https://github.com/shadowsocks/shadowsocks-qt5

然后找到里面有个叫做 cmakelist.txt 的文件。

我们需要往里面添加：

• 表示编译以后生成 DEB 包的设置
• 生成的 DEB 包的名称
• 安装完了以后的软件名称
• 依赖关系（我是从老版本的 DEB 包里解包找到的依赖关系 QwQ）
• include(CPack)

依赖关系里面我原本搞错了一个东西，就是现在的 libqtshadowsocks 依赖的是 botan-2，然而我原本弄成了 botan-1，这就会导致最后 ss-qt5 少那些新出的安全的 AEAD 加密方式（因为这个是包含在 botan-2 里的）

对于 libQtShadowsocks 的 cmakelist 我改成了这样：

cmake_minimum_required(VERSION 3.1)

project(QtShadowsocks
        VERSION 2.1.0
        LANGUAGES CXX)

option(BUILD_SHARED_LIBS "Build ${PROJECT_NAME} as a shared library" ON)

set(CPACK_GENERATOR "DEB")
set(CPACK_PACKAGE_NAME "QtShadowsocks_2.1.0")
set(CPACK_DEBIAN_PACKAGE_NAME "QtShadowsocks")
set(CPACK_DEBIAN_PACKAGE_DEPENDS "libbotan-2-dev (>= 2.4.0), libc6 (>= 2.14), libgcc1 (>= 1:3.0), libqt5core5a (>= 5.7.0), libqt5network5 (>= 5.6.0~beta), libstdc++6 (>= 5.2)")

set(LIB_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/lib
    CACHE PATH "Installation directory for libraries")
set(INCLUDE_INSTALL_DIR ${CMAKE_INSTALL_PREFIX}/include
    CACHE PATH "Installation directory for headers")
set(CMAKE_INCLUDE_CURRENT_DIR ON)
set(CMAKE_AUTOMOC ON)
set(CMAKE_CXX_STANDARD 14)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)

set(CPACK_PACKAGE_CONTACT "konnyakuxzy@outlook.com")
set(CPACK_DEBIAN_PACKAGE_MAINTAINER "XZYQvQ")

find_package(Qt5Core 5.5)
find_package(Qt5Network 5.5)
find_package(PkgConfig)

pkg_search_module(BOTAN REQUIRED botan-2>=2.3.0 botan-1.10)
if(BOTAN_VERSION VERSION_GREATER 2.0)
    message(STATUS "Botan-2 is found and will be used in this build")
    add_definitions(-DUSE_BOTAN2)
else()
    message(DEPRECATION "Botan-1.10 is found and will be used in this build. However, Botan-1.10 is deprecated and should not be used if possible")
endif()
find_library(BOTAN_LIBRARY_VAR
             NAMES ${BOTAN_LIBRARIES}
             HINTS ${BOTAN_LIBRARY_DIRS} ${BOTAN_LIBDIR})

if(BUILD_SHARED_LIBS)
    add_definitions(-DQSS_LIBRARY)
else()
    add_definitions(-DQSS_STATIC)
    if (MINGW)
        # This however doesn't fix the problem that the executables are depending on the GCC shared libraries
        # I can't find a solution in CMake so far. The workaround is to manually append "-l:libgcc.a -l:libstdc++.a -l:libwinpthread.a" to the end of executables' linklibs.rsp files (in CMakeFiles directory)
        set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc -static-libstdc++")
    endif()
endif()

if(WIN32 OR APPLE)
    add_definitions(-DFD_SETSIZE=1024)
endif()

add_subdirectory(lib)
add_subdirectory(shadowsocks-libqss)
find_package(Qt5Test)
if (Qt5Test_FOUND)
    # enable_testing() has to be in the root CMakeLists.txt, see https://cmake.org/pipermail/cmake/2010-November/040725.html
    enable_testing()
    add_subdirectory(test)
endif()

include(CPack)

对于 Shadowsocks-qt5 的 cmakelist 我改成了这样：

cmake_minimum_required(VERSION 3.1)

project(Shadowsocks-Qt5
        VERSION 3.0.1
        LANGUAGES CXX)

set(CPACK_GENERATOR "DEB")
set(CPACK_PACKAGE_NAME "shadowsocks-qt5_3.0.1")
set(CPACK_DEBIAN_PACKAGE_NAME "shadowsocks-qt5")
set(CPACK_DEBIAN_PACKAGE_DEPENDS "qtshadowsocks, libappindicator1 (>= 0.2.91), libc6 (>= 2.14), libgcc1 (>= 1:3.0), libglib2.0-0 (>= 2.12.0), libgtk2.0-0 (>= 2.16.0), libqrencode3 (>= 3.2.0), libqt5core5a (>= 5.7.0), libqt5dbus5 (>= 5.0.2), libqt5gui5 (>= 5.7.0) | libqt5gui5-gles (>= 5.7.0), libqt5network5 (>= 5.0.2), libqt5widgets5 (>= 5.2.0), libstdc++6 (>= 5.2), libzbar0 (>= 0.10)")

set(CMAKE_INCLUDE_CURRENT_DIR ON)
set(CMAKE_AUTOMOC ON)
set(CMAKE_AUTOUIC ON)
set(CMAKE_AUTORCC ON)
set(CMAKE_CXX_STANDARD 14)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)

set(CPACK_PACKAGE_CONTACT "konnyakuxzy@outlook.com")
set(CPACK_DEBIAN_PACKAGE_MAINTAINER "XZYQvQ")

find_package(Qt5Core)
find_package(Qt5Gui)
find_package(Qt5Widgets)
find_package(Qt5Network)
if(UNIX AND NOT APPLE)
    find_package(Qt5DBus)
endif()
find_package(PkgConfig)

pkg_check_modules(QSS REQUIRED QtShadowsocks>=2.0.0)
find_library(QSS_LIBRARY_VAR
    NAMES ${QSS_LIBRARIES}
    HINTS ${QSS_LIBRARY_DIRS} ${QSS_LIBDIR})

pkg_check_modules(QRENCODE REQUIRED libqrencode)
find_library(QRENCODE_LIBRARY_VAR
    NAMES ${QRENCODE_LIBRARIES}
    HINTS ${QRENCODE_LIBRARY_DIRS} ${QRENCODE_LIBDIR})

pkg_check_modules(ZBAR REQUIRED zbar)
find_library(ZBAR_LIBRARY_VAR
    NAMES ${ZBAR_LIBRARIES}
    HINTS ${ZBAR_LIBRARY_DIRS} ${ZBAR_LIBDIR})

if(WIN32 OR APPLE)
    add_definitions(-DFD_SETSIZE=1024)
endif()

add_subdirectory(src)

include(CPack)

记得安装一下依赖：

编译 lib 需要的依赖：

sudo apt-get install qt5-qmake qtbase5-dev libbotan1.10-dev g++ -y

编译 ss-qt5 需要的依赖：

sudo apt-get install qt5-qmake qtbase5-dev libqrencode-dev libappindicator-dev libzbar-dev libbotan1.10-dev -y

然后对于这两个项目，都进入主目录，然后：

mkdir build && cd build
cmake ..
make package

然后会在 build 文件夹就会生成出 DEB 安装包啦 233333～